devneko is not cat.

Alert.show()を使った場合、ダイアログの縦幅、横幅の最大サイズが設定されているおかげで想定外の表示を
してしまう場合がある。これを回避するために、Alertの拡張などを考えたのだけれど、肝心な部分がmx_internalだったり
privateだったりして、うまく拡張できなさそうだった。結局は一から作るハメになる。Flexではよくあること。
とりあえず MessageBox.mxml を作って以下を実現した。
・最大height,widthの拡張
・最大heightを越える場合はスクロールバーを表示。
ただのPanelを継承してるだけなので、あとは自由にカスタマイズできる。

AdvancedDataGridでセルの内容をコピーする方法は各所で紹介されているが
階層データやセル選択モード(MULTIPLE_CELLS)に対応しているものがない。
いろいろ試行錯誤した結果、AdvancedDataGridを継承して、下記のようなコードを書けば
選択中のセルの情報を取得できそうなことがわかった。
最初はlistItemsを使おうと思ったのだけれど、listItemsは基本的に表示中のアイテムしか
保持していないため、選択中のデータの取得には使えなかった。
それにしても、この程度のことが簡単にできないFlexにちょっと萎えた。


public var selectedCellDatas:Array = [];
override protected function addCellSelectionData(uid:String, columnIndex:int, selectionData:AdvancedDataGridBaseSelectionData):void {
	var column:AdvancedDataGridColumn = columns[selectionData.columnIndex] as AdvancedDataGridColumn;
	var label:String = column.itemToLabel(selectionData.data);
	selectedCellDatas.push({
		rowIndex: selectionData.rowIndex,
		columnIndex: selectionData.columnIndex,
		label: label
	});
	super.addCellSelectionData(uid, columnIndex, selectionData);
}
override protected function clearCellSelectionData():void {
	selectedCellDatas = [];
	super.clearCellSelectionData();
}

AdvancedDataGridにコンテキストメニューを開いた位置を取得したいときがあるのだが、なかなかうまい方法がなかった。
itemRollOverが発生した時に行と列を保存しておくという手法がちらほら書かれているが、試してみたところうまく機能しない場合があった。
稀にロールオーバーのイベントが飛んで来ずに、マウスのポイントしている位置とコンテキストメニューを開いた時に取得できる位置がずれてしまう。
そこで別の方法を探すことにしたのだが、なかなか良さそうな方法を見つけた。
AdavancedDataGridはデフォルトの状態で、マウスがポイントしている行やヘッダの背景色を変更する。
この背景色を変える処理を参考にして、ポイントしている位置を取得すればいい。
AdvancedDataGridはソースコードが公開されているので、mouseOverHandler()の実装を参考にして
うまくマウスのポイント位置から行と列を取得することができた。

この下記のサンプルだとコンテキストメニューのアイテムをクリックしたときに保存された行と列の情報にアクセスしているが
コンテキストメニューを開いた瞬間のマウスポイント位置のデータをうまく取得できる。
どうやら、コンテキストメニューを開いたあとはAdvancedDataGridのmouseOverHandler()が呼び出されないらしい。
もしメニューが開いたあともmouseOverHandler()が呼ばれる場合はContextMenuEvent.MENU_SELECTの発生時に
データを他に逃がす処理などを入れなければならなかったが、その必要はなくシンプルに実装できた。


<?xml version="1.0" encoding="utf-8"?>
<mx:AdvancedDataGrid xmlns:fx="http://ns.adobe.com/mxml/2009"
					 xmlns:s="library://ns.adobe.com/flex/spark"
					 xmlns:mx="library://ns.adobe.com/flex/mx"
					 creationComplete="advanceddatagrid1_creationCompleteHandler(event)">
	<fx:Declarations>
	</fx:Declarations>
	<fx:Script>
		<![CDATA[
			import mx.controls.Alert;
			import mx.controls.advancedDataGridClasses.AdvancedDataGridColumn;
			import mx.controls.listClasses.IDropInListItemRenderer;
			import mx.controls.listClasses.IListItemRenderer;
			import mx.events.FlexEvent;

			[Bindable]
			public var mouseOveredHeaderColumn:AdvancedDataGridColumn;
			[Bindable]
			public var mouseOveredColumn:AdvancedDataGridColumn;
			[Bindable]
			public var mouseOveredRow:int = -1;

			override protected function mouseOverHandler(event:MouseEvent):void {
				mouseOveredHeaderColumn = null;
				mouseOveredColumn = null;
				mouseOveredRow = -1;

				var item:IListItemRenderer = mouseEventToItemRenderer(event);
				var dropInItem:IDropInListItemRenderer;
				if (item) {
					dropInItem = item as IDropInListItemRenderer;
				}

				var colNum:int;
				if (dropInItem && dropInItem.listData) {
					colNum = dropInItem.listData.columnIndex;
				}
				if (dropInItem
					&& isHeaderItemRenderer(item)
					&& sortableColumns
					&& colNum != -1
					&& columns[colNum].sortable
					&& Object(item).hasOwnProperty("mouseEventToHeaderPart") )
				{
					var headerPart:String = Object(item).mouseEventToHeaderPart(event);
					mouseOveredHeaderColumn = item.data as AdvancedDataGridColumn;
				}
				else if ( item != null && !isHeaderItemRenderer(item) )
				{
					mouseOveredColumn = this.columns[colNum] as AdvancedDataGridColumn;
					var pt:Point = itemRendererToIndices(item);
					mouseOveredRow = pt.y;
				}
				super.mouseOverHandler(event);
			}

			protected function advanceddatagrid1_creationCompleteHandler(event:FlexEvent):void
			{
				var item:ContextMenuItem = new ContextMenuItem("くりっくみー");
				item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, clickListener);
				var cmenu:ContextMenu = new ContextMenu();
				cmenu.customItems.push(item);
				this.contextMenu = cmenu;
			}

			protected function clickListener(event:ContextMenuEvent):void {
				var str:String = "";
				str += "row:" + mouseOveredRow + "  ";
				if ( mouseOveredColumn ) {
					str += "column:" + mouseOveredColumn.headerText;
				}
				if ( mouseOveredHeaderColumn ) {
					str += "header:" + mouseOveredHeaderColumn.headerText;
				}
				Alert.show(str);
			}

		]]>
	</fx:Script>
</mx:AdvancedDataGrid>

BigDecimalの演算速度を検証しました。

検証の結果、以下のことがわかりました。
・ div/reminder は遅い
・ doubleのコンストラクタを使うと遅い
・ longのコンストラクタでも毎回newすると計算時間が増える。(まぁあたりまえだけど)
・桁が増えると遅くなる

BigDecimalは桁数に応じて内部データの持ち方を変えるようです。
桁が大きくなればなるほど遅くなると思われます。
データがintで表せる数である場合とlongで表せる数値の場合ではガクッと計算速度が変わります。

検証方法：
Core i 5 2500K 3.2GHz のマシンで100万回単純計算

検証コード：


import java.math.BigDecimal;
import java.math.MathContext;

public class Main {

	public static void main(String[] args) {
		long start,end;
		int repeat = 10000 * 100;

		start = System.currentTimeMillis();
		testAdd1D(repeat, 100000);
		end = System.currentTimeMillis();
		System.out.println("add1 loop内new double constructor 桁少なめ ms:" + (end - start));

		start = System.currentTimeMillis();
		testAdd1D(repeat, Long.MAX_VALUE);
		end = System.currentTimeMillis();
		System.out.println("add1 loop内new double constructor 桁多め ms:" + (end - start));

		start = System.currentTimeMillis();
		testAdd1L(repeat, 100000);
		end = System.currentTimeMillis();
		System.out.println("add1 loop内new long constructor 桁少なめ ms:" + (end - start));

		start = System.currentTimeMillis();
		testAdd1L(repeat, Long.MAX_VALUE);
		end = System.currentTimeMillis();
		System.out.println("add1 loop内new long constructor 桁多め ms:" + (end - start));

		start = System.currentTimeMillis();
		testAdd2(repeat, 100000);
		end = System.currentTimeMillis();
		System.out.println("add2 loop外new 桁少なめ ms:" + (end - start));

		start = System.currentTimeMillis();
		testAdd2(repeat, Long.MAX_VALUE);
		end = System.currentTimeMillis();
		System.out.println("sum2 loop外new 桁多め ms:" + (end - start));

		start = System.currentTimeMillis();
		testSub(repeat);
		end = System.currentTimeMillis();
		System.out.println("sub ms:" + (end - start));

		start = System.currentTimeMillis();
		testMul(repeat);
		end = System.currentTimeMillis();
		System.out.println("mul ms:" + (end - start));

		start = System.currentTimeMillis();
		testDiv(repeat);
		end = System.currentTimeMillis();
		System.out.println("div ms:" + (end - start));

		start = System.currentTimeMillis();
		testMod(repeat);
		end = System.currentTimeMillis();
		System.out.println("mod ms:" + (end - start));
	}

	public static BigDecimal testAdd1D(int repeat, double value) {
		BigDecimal sum = BigDecimal.valueOf(23423234.2344);
		for ( int i = 0; i < repeat; i++ ) {
			sum = sum.add(new BigDecimal(value));
		}
		return sum;
	}
	public static BigDecimal testAdd1L(int repeat, long value) {
		BigDecimal sum = BigDecimal.valueOf(23423234.2344);
		for ( int i = 0; i < repeat; i++ ) {
			sum = sum.add(new BigDecimal(value));
		}
		return sum;
	}

	public static BigDecimal testAdd2(int repeat, double value) {
		BigDecimal v = BigDecimal.valueOf(value);
		BigDecimal sum = BigDecimal.valueOf(23423234.2344);
		for ( int i = 0; i < repeat; i++ ) {
			sum = sum.add(v);
		}
		return sum;
	}

	public static BigDecimal testSub(int repeat) {
		BigDecimal sum = BigDecimal.valueOf(234342749.2342342);
		for ( int i = 0; i < repeat; i++ ) {
			sum = sum.subtract(new BigDecimal(1234234.234));
		}
		return sum;
	}

	public static BigDecimal testMul(int repeat) {
		BigDecimal d2 = BigDecimal.valueOf(1123234242.3421);
		for ( int i = 0; i < repeat; i++ ) {
			d2.multiply(new BigDecimal(122343.4));
		}
		return null;
	}

	public static BigDecimal testDiv(int repeat) {
		MathContext mc = new MathContext(20);
		BigDecimal d2 = BigDecimal.valueOf(122343412.3421);
		for ( int i = 0; i < repeat; i++ ) {
			d2.divide(new BigDecimal(12234.34), mc);
		}
		return null;
	}

	public static BigDecimal testMod(int repeat) {
		MathContext mc = new MathContext(20);
		BigDecimal d2 = BigDecimal.valueOf(1223434.123421);

		for ( int i = 0; i < repeat; i++ ) {
			d2.remainder(new BigDecimal(123423.234234),mc);
		}
		return null;
	}
}

出力：
add1 loop内new double constructor 桁少なめ ms:327
add1 loop内new double constructor 桁多め ms:625
add1 loop内new long constructor 桁少なめ ms:30
add1 loop内new long constructor 桁多め ms:90
add2 loop外new 桁少なめ ms:18
sum2 loop外new 桁多め ms:78
sub ms:411
mul ms:444
div ms:971
mod ms:1275

AdvancedDataGridにXMLをdataProviderとして与えてツリー表示をする場合などに、HierarchicalDataを使います。
HierarchicalData#childrenFiedlで子ノードを格納する要素名を指定できるのですが、特に表示用に作ったわけでもないXMLである場合、子ノードを
格納する要素の名前が同じであるとは限りません。この場合、childrenFieldでは対応できなくなります。
そこで、子ノードの判定を行う関数を指定できるIHierarchicalDataの実装があると便利です。

というわけで作ってみました。コンストラクタで判定関数を指定できるようになっています。
あと、Xmlに特化している分、HierarchicalDataより高速に動くというメリットもあります。(たぶん)


import flash.events.EventDispatcher;
import mx.events.CollectionEvent;
import mx.events.CollectionEventKind;
import mx.collections.IHierarchicalData;

public class XmlHierarchicalData extends EventDispatcher implements IHierarchicalData
{
	private var _source:XMLList;
	private var getChildrenFieldName:Function;

	public function XmlHierarchicalData(value:XMLList, childrenNameFunc:Function) {
		source = value;
		getChildrenFieldName = childrenNameFunc;
	}

	public function get source():XMLList
	{
		return _source;
	}

	public function set source(value:XMLList):void
	{
		_source = value;

		var event:CollectionEvent = new CollectionEvent(CollectionEvent.COLLECTION_CHANGE);
		event.kind = CollectionEventKind.RESET;
		dispatchEvent(event);
	}

	public function canHaveChildren(node:Object):Boolean
	{
		if (node == null) {
			return false;
		}
		var list:XMLList = getChildren(node) as XMLList;
		return list.length() > 0;
	}

	public function hasChildren(node:Object):Boolean
	{
		if (node == null) {
			return false;
		}
		var children:XMLList = XMLList(getChildren(node));
		return children.length() > 0;
	}

	public function getChildren(node:Object):Object
	{
		if ( node == null ) {
			return null;
		}
		var xml:XML = XML(node);
		var name:String = String(xml.localName());
		var childrenField:String = getChildrenFieldName(xml) as String;
		return xml.child(childrenField).*;
	}

	public function getData(node:Object):Object
	{
		return node;
	}

	public function getRoot():Object
	{
		return _source;
	}
}

月	火	水	木	金	土	日
« 12月
						1
2	3	4	5	6	7	8
9	10	11	12	13	14	15
16	17	18	19	20	21	22
23	24	25	26	27	28	29
30	31

devneko is not cat.

FlexのAlert.show()でテキストが折り返される問題の回避。

AdvancedDataGridでセルの内容をコピーするには。セル選択モード、階層データ対応。

AdvancedDataGridでコンテキストメニューを開いた位置の列と行を取得する。

BigDecimalの演算速度を検証してみた。

子ノード(childrenField)の判定を柔軟に行えるIHierarchicalData実装

自己紹介

Meta

devneko is not cat.

FlexのAlert.show()でテキストが折り返される問題の回避。

AdvancedDataGridでセルの内容をコピーするには。セル選択モード、階層データ対応。

AdvancedDataGridでコンテキストメニューを開いた位置の列と行を取得する。

BigDecimalの演算速度を検証してみた。

子ノード(childrenField)の判定を柔軟に行えるIHierarchicalData実装

自己紹介

Meta

タグ